
    Rexsilient

Rexsilient is a resilience toolkit for Elixir, inspired by
Polly and
Hystrix. Like them, it gives
applications the patterns to stay up when the services they depend on fail
or slow down.
OTP supervisors take care of your processes when they crash. Rexsilient
complements them for the calls to dependencies outside your supervision
tree, such as databases, APIs and other services.
	Pattern	Purpose	Status
	Circuit breaker	Stop calling a dependency that keeps failing	Available
	Retry	Retry transient failures, with backoff	Available
	Fallback	Provide an alternative result when a call fails	Available
	Timeout	Give up on calls that take too long	Planned
	Bulkhead	Limit concurrent calls to a dependency	Planned

Read the full documentation on hexdocs.pm.
Installation
Add :rexsilient to your dependencies in mix.exs:
def deps do
  [
    {:rexsilient, "~> 1.0"}
  ]
end
Getting started
Patterns are declared in a module that uses Rexsilient. A module may
declare as many as needed, of any kind:
defmodule MyApp.Resilience do
  use Rexsilient

  alias Rexsilient.CircuitBreaker.{Recover, Strategy}

  circuit_breaker :payments do
    strategy Strategy.Count, threshold: 5
    recover Recover.BasicTimeout,
      reset_timeout: :timer.seconds(30),
      probing_timeout: :timer.seconds(10)
  end
end
Rexsilient is added to your supervision tree with every module that declares
patterns, before the processes that use them:
children = [
  {Rexsilient, modules: [MyApp.Resilience]},
  MyAppWeb.Endpoint
]
Functions that call the dependency are then annotated with the circuit
breaker:
defmodule MyApp.Payments do
  use Rexsilient.Decorator

  @circuit_breaker :payments
  def charge(order) do
    PaymentsClient.charge(order)
  end
end
Every call to MyApp.Payments.charge/1 now goes through the circuit breaker.
While it is open, it returns {:error, :circuit_open} without calling the
dependency.
Usage
Circuit breaker
A circuit breaker watches the calls made to a dependency. When its strategy
decides there were too many failures, it opens: calls are rejected
immediately, without reaching the dependency. After the wait set by its
recover module, it lets a single call through as a probe. If the probe
succeeds, the circuit breaker closes and traffic resumes. If it fails, the
circuit breaker opens again. If it takes too long, also set by the recover
module, another call is let through as the probe and the slow one's result is
ignored.
Built-in strategies and recovery modules:
	Setting	Module	Behaviour
	strategy	Strategy.Count	Opens after threshold failures since the circuit breaker last closed
	strategy	Strategy.SlidingWindow	Opens after threshold failures within window milliseconds
	recover	Recover.BasicTimeout	Stays open for reset_timeout milliseconds; gives a probe probing_timeout milliseconds

The easiest way to use it is the @circuit_breaker decorator, as in
Getting started. Without a decorator, a call goes through
the circuit breaker with run/3:
alias Rexsilient.CircuitBreaker

case CircuitBreaker.run(:payments, fn -> PaymentsClient.charge(order) end) do
  {:ok, receipt} -> {:ok, receipt}
  {:error, :circuit_open} -> {:error, :payments_unavailable}
  {:error, reason} -> {:error, reason}
end
run/3 returns the function's result unchanged, and re-raises its exceptions
unchanged after recording them, so the circuit breaker is transparent to the
caller. When the circuit breaker is open, it returns {:error, :circuit_open}
and the function is not called. The rejection value can be changed:
CircuitBreaker.run(:payments, fun, on_open: {:error, :unavailable})
To compute another result instead, such as a cached value, wrap the call in a
fallback, which always replaces {:error, :circuit_open}.
What counts as a failure is set by the module that declares the circuit
breaker; see Classifying failures.
The circuit breaker's state can be inspected with status/1:
CircuitBreaker.status(:payments)
#=> :closed | :open | :half_open | :probing
Operators can force a circuit breaker open, for example while the dependency
is under maintenance, and close it again:
CircuitBreaker.force_open(:payments)
CircuitBreaker.force_close(:payments)
A forced-open circuit breaker rejects every call until force_close/1; no
probe is let through.
Checking a circuit breaker is a single atomic read in the calling process,
with no message to any process, so it scales with the number of schedulers.
A single manager process owns timers and state changes for every circuit
breaker. If it crashes, it restarts every circuit breaker closed, so a failure
of the circuit breaker itself never blocks traffic.
Retry
A retry calls a function again when it fails, waiting between attempts as its
strategy decides:
retry :payments do
  attempts 4
  strategy Rexsilient.Retry.Strategy.Exponential,
    base_delay: 100,
    max_delay: 5_000,
    jitter: :full
end
The easiest way to use it is the @retry decorator:
defmodule MyApp.Payments do
  use Rexsilient.Decorator

  @retry :payments
  def charge(order) do
    PaymentsClient.charge(order)
  end
end
Without a decorator, a call is retried with run/2:
Rexsilient.Retry.run(:payments, fn -> PaymentsClient.charge(order) end)
attempts is the total number of calls, the first one included, or
:infinity to leave the limit to the strategy. A retry runs entirely in the
calling process, which sleeps between attempts. When no attempts remain, or the strategy stops, the last outcome is
returned unchanged: the value the function returned, or what it raised, threw
or exited with, re-raised with its original stacktrace.
Built-in strategies:
	Module	Behaviour
	Strategy.Constant	Waits delay milliseconds before every attempt
	Strategy.Exponential	Doubles the wait from base_delay up to max_delay; jitter: :full or :equal randomizes it
	Strategy.Decorrelated	Waits a random time from base_delay to three times the previous wait, up to max_delay

{:error, :circuit_open} is never retried: a circuit breaker just said the
dependency is down, and retrying would only wait for the same answer.
Fallback
A fallback replaces the outcome of a failed call with the result of another
function:
fallback :prices do
  function :cached_price
end

def cached_price(sku), do: Cache.last_price(sku)
The easiest way to use it is the @fallback decorator. The fallback function
is called with the decorated function's arguments:
defmodule MyApp.Prices do
  use Rexsilient.Decorator

  @fallback :prices
  def fetch(sku) do
    PricesClient.fetch(sku)
  end
end
Without a decorator, a call goes through the fallback with run/3, whose
third argument is passed to both functions; use a list or a tuple to pass
several values:
Rexsilient.Fallback.run(:prices, fn sku -> PricesClient.fetch(sku) end, sku)
function names a function of the declaring module, or {module, name} for
one in another module. A raise, throw or exit counted as a failure is
replaced too, not re-raised.
{:error, :circuit_open} is always replaced, so a fallback around a circuit
breaker answers while the circuit breaker is open. An error raised by the
fallback function itself propagates to the caller. A fallback runs entirely
in the calling process.
Decorators
@circuit_breaker, @retry and @fallback are available in any module that
has use Rexsilient.Decorator. Options for CircuitBreaker.run/3 go in a
keyword list with the name under :name:
@circuit_breaker name: :payments, on_open: {:error, :unavailable}
Only public functions can be decorated, and the attribute applies to every
clause of that name and arity. See Rexsilient.Decorator for the details.
Classifying failures
By default, a call fails when the function returns :error or {:error, _},
or when it raises, throws or exits. Every other return value counts as a
success. This applies to circuit breakers, retries and fallbacks alike.
To change it, override classify/1, for returned values, and classify/2,
for raises, throws and exits, in the module that declares the patterns:
@impl true
def classify({:error, %{status: status}}) when status >= 500, do: :failure
def classify(_), do: :success
The two are independent: overriding classify/1 keeps the default
classify/2, so exceptions still count as failures.
To classify one declaration differently from the others in the same module,
name other functions with classify_with:
circuit_breaker :search do
  strategy Rexsilient.CircuitBreaker.Strategy.Count, threshold: 10
  recover Rexsilient.CircuitBreaker.Recover.BasicTimeout,
    reset_timeout: :timer.seconds(5),
    probing_timeout: :timer.seconds(2)
  classify_with :classify_search
end

def classify_search({:error, :not_found}), do: :success
def classify_search(result), do: classify(result)
A missing classify_search/2 falls back to classify/2. See
Rexsilient.Classify.
Combining patterns
Fallback, retry and circuit breaker can protect the same call. Combined, they
nest in a fixed order: the fallback outside, the retry in the middle and the
circuit breaker inside, next to the call.
fallback( retry( circuit_breaker( call ) ) )
	Every attempt goes through the circuit breaker, so it counts each real
failure.
	The retry stops as soon as the circuit breaker is open, instead of waiting
on it.
	The fallback sees the final outcome, the last failure or the circuit
breaker's rejection, and replaces it.

Each pattern keeps its own declaration and classifier. Patterns of different
kinds can share a name. A policy groups them under one name, referencing
each declaration by its name:
defmodule MyApp.Resilience do
  use Rexsilient

  alias Rexsilient.CircuitBreaker.{Recover, Strategy}
  alias Rexsilient.Retry

  fallback :prices do
    function :cached_price
  end

  retry :prices do
    attempts 3
    strategy Retry.Strategy.Exponential, base_delay: 100, max_delay: 2_000, jitter: :full
  end

  circuit_breaker :prices do
    strategy Strategy.Count, threshold: 5
    recover Recover.BasicTimeout,
      reset_timeout: :timer.seconds(30),
      probing_timeout: :timer.seconds(10)
  end

  policy :prices do
    fallback :prices
    retry :prices
    circuit_breaker :prices
  end

  def cached_price(sku), do: Cache.last_price(sku)
end
The policy is then used with @policy from Rexsilient.Decorator:
defmodule MyApp.Prices do
  use Rexsilient.Decorator

  @policy :prices
  def fetch(sku) do
    PricesClient.fetch(sku)
  end
end
Any entry of a policy can be left out, for example a fallback around a
circuit breaker with no retry. Names that are not declared raise an error
when Rexsilient starts.
Without a policy, the same result comes from stacking the decorators, which
nest in the same order whatever the order they are written in:
@fallback :prices
@retry :prices
@circuit_breaker :prices
def fetch(sku) do
  PricesClient.fetch(sku)
end
or from nesting the calls:
alias Rexsilient.{CircuitBreaker, Fallback, Retry}

Fallback.run(:prices, fn sku ->
  Retry.run(:prices, fn ->
    CircuitBreaker.run(:prices, fn -> PricesClient.fetch(sku) end)
  end)
end, sku)
Other orders
The fixed order fits most cases. A few need another one, for example:
	A circuit breaker outside the retry, so that it counts a whole retry
sequence as one call and opens only on calls that still fail after every
attempt.
	The same pattern twice, such as a circuit breaker per host inside a circuit
breaker for the whole service.

For these, decorate one function per layer, each calling the next:
@circuit_breaker :prices
def fetch(sku), do: fetch_with_retry(sku)

@doc false
@retry :prices
def fetch_with_retry(sku), do: PricesClient.fetch(sku)
Inner layers are public
Decorated functions must be public, so calling the inner one directly skips
the outer layer.
or nest the calls in the order you need:
CircuitBreaker.run(:prices, fn ->
  Retry.run(:prices, fn -> PricesClient.fetch(sku) end)
end)
Notifications
Rexsilient tells notifiers what the patterns are doing: every call, and
every change of state. A notifier is a module that implements
Rexsilient.Notifier, listed in the :notifiers option of Rexsilient.
The default is [Rexsilient.Notifier.TelemetryNotifier]; listing other
notifiers replaces it, so include it to keep it.
Each notification has a moment, the pattern that sends it, and a state map
with its :name:
	Pattern	Moments
	Circuit breaker	:before and :after a call, :rejected, and :open, :half_open, :probing and :closed when it changes state
	Retry	:before and :after each attempt, :delay before waiting, and :stop when no attempt follows
	Fallback	:before and :after the fallback function

See Rexsilient.Notifier for the state of each moment. Notifiers other than
TelemetryNotifier are called by a single notifier process, so the call being
notified never waits for them.
Notifying has a cost even when nothing listens, so pass notifiers: [] to
turn it off:
{Rexsilient, modules: [MyApp.Resilience], notifiers: []}
Telemetry
Rexsilient.Notifier.TelemetryNotifier, the default notifier, emits every
notification as a :telemetry event named [:rexsilient, kind, event],
where kind is :circuit_breaker, :retry or :fallback. Unlike other
notifiers, it runs in the calling process, so handlers see the caller's
context and must be fast.
:telemetry.attach(
  "log-open-circuit-breakers",
  [:rexsilient, :circuit_breaker, :open],
  fn _event, _measurements, %{name: name, from: from}, _config ->
    Logger.warning("circuit breaker #{inspect(name)} opened from #{from}")
  end,
  nil
)
Events follow the :telemetry.span/3 conventions: :before is emitted as
:start and :after as :stop, and the retry's :stop moment as
:give_up. Numeric values are measurements, and the rest is metadata:
[:rexsilient, :circuit_breaker, event]:
	Event	Measurements	Metadata
	:start	monotonic_time, system_time	name
	:stop	monotonic_time, duration	name, result, outcome
	:rejected	system_time	name
	:open	system_time, timeout	name, from, outcome, forced¹
	:half_open	system_time	name, from
	:probing	system_time, timeout	name, from, outcome
	:closed	system_time	name, from, forced¹, restart¹

¹ Only present when the change was forced with force_open/1 or
force_close/1, or caused by a manager restart. A forced :open has
timeout: :infinity, in the metadata.
[:rexsilient, :retry, event]:
	Event	Measurements	Metadata
	:start	monotonic_time, system_time	name, attempt
	:stop	monotonic_time, duration	name, attempt, result, outcome
	:delay	delay	name, attempt, outcome
	:give_up	duration	name, attempt, outcome, reason

[:rexsilient, :fallback, event]:
	Event	Measurements	Metadata
	:start	monotonic_time, system_time	name, outcome (the one replaced)
	:stop	monotonic_time, duration	name, outcome

Times and duration are in native time units, delay and timeout in
milliseconds. result is :success or :failure, and outcome is
{:value, value} or {kind, reason}.
Running tests
$ mix deps.get
$ mix test

License
Rexsilient is released under the MIT License; see LICENSE.

Rexsilient is a resilience toolkit for Elixir. Its patterns protect the calls
an application makes to its dependencies:
	Rexsilient.CircuitBreaker - stops calling a dependency that keeps
failing.

	Rexsilient.Retry - calls a function again when it fails, with backoff.

	Rexsilient.Fallback - replaces the outcome of a failed call with the
result of another function.


Declaring patterns
Patterns are declared in any module that uses Rexsilient. A module may
declare as many as needed, of any kind:
defmodule MyApp.Resilience do
  use Rexsilient

  alias Rexsilient.CircuitBreaker.{Recover, Strategy}

  circuit_breaker :payments do
    strategy Strategy.Count, threshold: 5
    recover Recover.BasicTimeout,
      reset_timeout: :timer.seconds(30),
      probing_timeout: :timer.seconds(10)
  end

  retry :payments do
    attempts 4
    strategy Rexsilient.Retry.Strategy.Exponential, base_delay: 100, max_delay: 5_000
  end

  fallback :prices do
    function :cached_price
  end

  def cached_price(sku), do: Cache.last_price(sku)
end
Declarations are checked at compile time: a missing required setting, a
setting used outside the block it belongs to, or one set twice fails
compilation with an error that points at the offending line. The options of
each setting are checked when the declaration is registered.
The module is then passed to Rexsilient in your supervision tree, which
registers its declarations when it starts:
children = [
  {Rexsilient, modules: [MyApp.Resilience]},
  MyAppWeb.Endpoint
]
List it before the processes that use the declarations, so they exist when
they are first used. See child_spec/1 for the options.
Settings
	circuit_breaker/2 - strategy/2 and recover/2, required, and
classify_with/1.

	retry/2 - attempts/1 and strategy/2, required, and
classify_with/1.

	fallback/2 - function/1, required, and classify_with/1.

	policy/2 - at least one of fallback/1, retry/1 and
circuit_breaker/1.


Modules and options are evaluated at compile time, so aliases and
expressions such as :timer.seconds(30) are allowed.
Using patterns
The easiest way is to annotate the functions that call the dependency, with
Rexsilient.Decorator:
defmodule MyApp.Payments do
  use Rexsilient.Decorator

  @retry :payments
  @circuit_breaker :payments
  def charge(order) do
    PaymentsClient.charge(order)
  end
end
Without a decorator, calls go through Rexsilient.CircuitBreaker.run/3,
Rexsilient.Retry.run/2 and Rexsilient.Fallback.run/3.
Classifying failures
use Rexsilient defines classify/1 and classify/2, which decide which
outcomes count as failures for every pattern declared in the module: by
default, :error, {:error, _} and any raise, throw or exit. Override them,
or name other functions with classify_with/1; see Rexsilient.Classify.

positive integer, or :infinity to leave the limit to the strategy.

        Returns a child specification that registers the declarations of the given

        References the circuit breaker name in a policy. Can only be used inside
policy/2.

        Sets the name of the functions, in the declaring module, that decide which
outcomes are failures, instead of classify/1 and classify/2. A missing
func_name/1 or func_name/2 falls back to the classify one of the same
arity; see Rexsilient.Classify.

        Sets the function a fallback calls when the call fails: a name, for a
function in the declaring module, or {module, name} for one in another
module. It is called with the same arguments as the failed call.

        Declares a policy called name: a fallback, a retry and a circuit breaker,
each referenced by the name it is declared with, used together with
@policy name from Rexsilient.Decorator.

and how long a probe may run before the breaker lets another one through.

policy/2.



    


    
      
        retry(name, list)

      


        Declares a retry called name.



    


    
      
        strategy(module, opts)

      


        Sets the strategy of a breaker or a retry.



    





      


      
        Functions


        


  
    
      
    
    
      attempts(number)


        (macro)


        
          
        

    

  


  

Sets the total number of calls a retry makes, the first one included: a
positive integer, or :infinity to leave the limit to the strategy.
Can only be used inside retry/2.
Examples
attempts 4

          @spec child_spec(opts :: [modules: [module()], notifiers: [module()]]) ::
  Supervisor.child_spec()


      


Returns a child specification that registers the declarations of the given
modules and starts the processes they need.
Options
	:modules - the modules that declare with Rexsilient. Required.
Raises ArgumentError if two declarations of the same kind share a
name.

	:notifiers - the modules told what the patterns are doing; see
Rexsilient.Notifier. Defaults to
[Rexsilient.Notifier.TelemetryNotifier]; [] sends nothing.


Examples
children = [
  {Rexsilient, modules: [MyApp.Resilience], notifiers: [MyApp.Notifier]}
]

References the circuit breaker name in a policy. Can only be used inside
policy/2.

Declares a circuit breaker called name.
name must be an atom, unique among all breakers registered on the node.
The block sets the breaker's settings; see Settings.
Examples
circuit_breaker :payments do
  strategy Rexsilient.CircuitBreaker.Strategy.Count, threshold: 5
  recover Rexsilient.CircuitBreaker.Recover.BasicTimeout,
    reset_timeout: :timer.seconds(30),
    probing_timeout: :timer.seconds(10)
end

Sets the name of the functions, in the declaring module, that decide which
outcomes are failures, instead of classify/1 and classify/2. A missing
func_name/1 or func_name/2 falls back to the classify one of the same
arity; see Rexsilient.Classify.
Can only be used inside circuit_breaker/2, fallback/2 or retry/2.
Examples
classify_with :classify_payments

References the fallback name in a policy. Can only be used inside
policy/2.

Declares a fallback called name.
name must be an atom, unique among all fallbacks registered on the node.
The block sets the fallback's settings; see Rexsilient.Fallback.
Examples
fallback :prices do
  function :cached_price
end

Sets the function a fallback calls when the call fails: a name, for a
function in the declaring module, or {module, name} for one in another
module. It is called with the same arguments as the failed call.
Can only be used inside fallback/2.
Examples
function :cached_price

function {MyApp.Cache, :last_price}

Declares a policy called name: a fallback, a retry and a circuit breaker,
each referenced by the name it is declared with, used together with
@policy name from Rexsilient.Decorator.
The block lists the declarations with fallback/1, retry/1 and
circuit_breaker/1. Each one is optional, but at least one is required.
They always nest in the same order, whatever the order they are written in:
fallback( retry( circuit_breaker( call ) ) )
The referenced declarations may live in any module registered with
Rexsilient. A name that is not declared raises ArgumentError when the
policy is registered.
Examples
policy :prices do
  fallback :prices
  retry :prices
  circuit_breaker :prices
end

Sets how long the breaker stays open before it lets a probe call through,
and how long a probe may run before the breaker lets another one through.
opts are passed to module and only read by it. Can only be used inside
circuit_breaker/2.
Examples
recover Rexsilient.CircuitBreaker.Recover.BasicTimeout,
  reset_timeout: :timer.seconds(30),
  probing_timeout: :timer.seconds(10)

References the retry name in a policy. Can only be used inside
policy/2.

Declares a retry called name.
name must be an atom, unique among all retries registered on the node.
The block sets the retry's settings; see Rexsilient.Retry.
Examples
retry :payments do
  attempts 4
  strategy Rexsilient.Retry.Strategy.Exponential, base_delay: 100, max_delay: 5_000
end

  



  
    
      
    
    
      strategy(module, opts)


        (macro)


        
          
        

    

  


  

Sets the strategy of a breaker or a retry.
Inside circuit_breaker/2, it decides when the breaker opens; see
Rexsilient.CircuitBreaker.Strategy. Inside retry/2, it decides how long
to wait before the next attempt, or whether to stop; see
Rexsilient.Retry.Strategy.
opts are passed to module and only read by it. Can only be used inside
circuit_breaker/2 or retry/2.
Examples
strategy Rexsilient.CircuitBreaker.Strategy.Count, threshold: 5

strategy Rexsilient.Retry.Strategy.Exponential, base_delay: 100, max_delay: 5_000

Circuit breakers stop calls to a dependency that keeps failing.
When a dependency fails repeatedly, calling it again usually fails too: it
wastes the caller's time and adds load to a service that is already
struggling. A circuit breaker watches the calls made to the dependency and,
after too many failures, rejects them immediately until the dependency has
had time to recover.
A circuit breaker is declared in a module that uses Rexsilient:
defmodule MyApp.Resilience do
  use Rexsilient

  alias Rexsilient.CircuitBreaker.{Recover, Strategy}

  circuit_breaker :payments do
    strategy Strategy.Count, threshold: 5
    recover Recover.BasicTimeout,
      reset_timeout: :timer.seconds(30),
      probing_timeout: :timer.seconds(10)
  end
end
and used with @circuit_breaker :payments from Rexsilient.Decorator:
defmodule MyApp.Payments do
  use Rexsilient.Decorator

  @circuit_breaker :payments
  def charge(order) do
    PaymentsClient.charge(order)
  end
end
or, without a decorator, with run/3:
case Rexsilient.CircuitBreaker.run(:payments, fn -> PaymentsClient.charge(order) end) do
  {:ok, receipt} -> {:ok, receipt}
  {:error, :circuit_open} -> {:error, :payments_unavailable}
  {:error, reason} -> {:error, reason}
end
States
A breaker is always in one of four states, returned by status/1:
	:closed - calls go through. Their results are passed to the
breaker's strategy, which decides when it opens.

	:open - calls are rejected without reaching the dependency. After the
time set by its recover module, the breaker becomes half-open.

	:half_open - the next call is let through as a probe, to test
whether the dependency has recovered.

	:probing - the probe is running. Every other call is rejected. If the
probe succeeds, the breaker closes and its strategy is reset. If it
fails, the breaker opens again. If it runs longer than the time set by
the recover module, the breaker becomes half-open again and the slow
probe's result is ignored.


Exactly one caller becomes the probe, even when many arrive at once.
Failures
Whether a call counts as a failure is decided by the classify/1 and
classify/2 functions of the module that declares the breaker, or by the
functions named with classify_with in the breaker's declaration. By
default, a call fails when the function returns :error or {:error, _},
or when it raises, throws or exits; every other return value counts as a
success. See Rexsilient.Classify to change it.
Starting
Breakers are registered by a single manager process, started by Rexsilient
in your supervision tree with the modules that declare them:
children = [
  {Rexsilient, modules: [MyApp.Resilience]}
]
Checking a breaker does not involve the manager: it is a single atomic read
in the calling process, so it scales with the number of schedulers. The
manager only handles state changes and timers. If it crashes, every breaker
restarts closed, so a failure of the breaker itself never blocks traffic.

      


      
        Summary


  
    Types
  


    
      
        name()

      


        The name a breaker is declared with.



    


    
      
        state_counter()

      


        Identifies the state a call was allowed in. Returned by acquire/1 and
passed unchanged to release/4.



    


    
      
        status()

      


        The state of a breaker; see States.



    





  
    Functions
  


    
      
        acquire(name)

      


        Asks the breaker name whether a call may go through.



    


    
      
        child_spec(init_arg)

      


        Returns a specification to start this module under a supervisor.



    


    
      
        force_close(name)

      


        Forces the breaker name closed, and resets its strategy.



    


    
      
        force_open(name)

      


        Forces the breaker name open.



    


    
      
        release(name, result, state_counter, outcome \\ nil)

      


        Records the result of a call allowed by acquire/1.



    


    
      
        run(name, func, opts \\ [])

      


        Calls func through the breaker name.



    


    
      
        start_link(opts)

      


        Starts the breaker manager and registers the declared breakers.



    


    
      
        status(name)

      


        Returns the current state of the breaker name.



    





      


      
        Types


        


  
    
      
    
    
      name()



        
          
        

    

  


  

      

          @type name() :: atom()


      


The name a breaker is declared with.

  



  
    
      
    
    
      state_counter()



        
          
        

    

  


  

      

          @type state_counter() :: non_neg_integer()


      


Identifies the state a call was allowed in. Returned by acquire/1 and
passed unchanged to release/4.

  



  
    
      
    
    
      status()



        
          
        

    

  


  

      

          @type status() :: :closed | :open | :half_open | :probing


      


The state of a breaker; see States.

  


        

      

      
        Functions


        


  
    
      
    
    
      acquire(name)



        
          
        

    

  


  

      

          @spec acquire(name()) :: {:ok, state_counter()} | {:error, :circuit_open}


      


Asks the breaker name whether a call may go through.
Returns {:ok, state_counter} if the call is allowed, or
{:error, :circuit_open} if it is rejected. When the breaker is half-open,
the caller that gets {:ok, _} becomes the probe.
Together with release/4, it is the building block of run/3. Use them
directly when run/3 does not fit, for example when what counts as a
failure depends on the call site rather than on the breaker's classify/1.
After an allowed call, pass its result, state_counter and outcome to
release/4.
They are only the breaker's state machine, without anything run/3 adds
around it: no classify, no catching of raises, throws and exits, no
:on_open, and no :before, :after or :rejected notifications. Only
the state changes caused by release/4 are notified.
Raises ArgumentError if no breaker is registered under name.
Examples
Counting only server errors as failures:
case Rexsilient.CircuitBreaker.acquire(:payments) do
  {:ok, state_counter} ->
    try do
      PaymentsClient.charge(order)
    catch
      kind, reason ->
        Rexsilient.CircuitBreaker.release(:payments, :failure, state_counter, {kind, reason})
        :erlang.raise(kind, reason, __STACKTRACE__)
    else
      %{status: status} = response when status >= 500 ->
        Rexsilient.CircuitBreaker.release(:payments, :failure, state_counter, {:value, response})
        response

      response ->
        Rexsilient.CircuitBreaker.release(:payments, :success, state_counter, {:value, response})
        response
    end

  {:error, :circuit_open} ->
    {:error, :payments_unavailable}
end

  



  
    
      
    
    
      child_spec(init_arg)



        
          
        

    

  


  

Returns a specification to start this module under a supervisor.
See Supervisor.

  



  
    
      
    
    
      force_close(name)



        
          
        

    

  


  

      

          @spec force_close(name()) :: :ok


      


Forces the breaker name closed, and resets its strategy.
Works from any state, including after force_open/1. Timers armed before
it are ignored, and so are the results of calls allowed before it.
Raises ArgumentError if no breaker is registered under name.
Examples
Rexsilient.CircuitBreaker.force_close(:payments)
Rexsilient.CircuitBreaker.status(:payments)
#=> :closed

  



  
    
      
    
    
      force_open(name)



        
          
        

    

  


  

      

          @spec force_open(name()) :: :ok


      


Forces the breaker name open.
Calls are rejected until force_close/1 is called: unlike a trip, no timer
makes the breaker half-open, and no probe is let through. Meant for
operators, for example to stop traffic to a dependency under maintenance.
Calls already allowed, and probes already running, finish normally, but
their results are ignored.
Raises ArgumentError if no breaker is registered under name.
Examples
Rexsilient.CircuitBreaker.force_open(:payments)
Rexsilient.CircuitBreaker.status(:payments)
#=> :open

  



    

  
    
      
    
    
      release(name, result, state_counter, outcome \\ nil)



        
          
        

    

  


  

      

          @spec release(
  name(),
  Rexsilient.Classify.result(),
  state_counter(),
  Rexsilient.Classify.outcome() | nil
) :: :ok


      


Records the result of a call allowed by acquire/1.
result is :success or :failure, as decided by the caller, and
state_counter is the value returned by acquire/1; pass it unchanged.
Results recorded with a counter from a previous state are ignored, so a slow
call cannot affect a breaker that has since changed state.
outcome is what the call produced, {:value, value} or {kind, reason}.
When the failure opens the breaker, it is passed to the recover module, so
it can decide how long to stay open from the error itself, for example from
a Retry-After header. It is optional; without it, the recover module
gets nil.
Release every acquire
Call it exactly once for every successful acquire/1, including when the
call raises. If the call was a probe and is not released in time, the
breaker stays in :probing, rejecting calls, until the probing timeout set
by its recover module makes it half-open again. See acquire/1 for an
example.
The result is recorded in the calling process, so a call that opens or
closes the breaker is reflected by status/1 as soon as release/4
returns. Only the timers that make a breaker half-open run in the manager.

  



    

  
    
      
    
    
      run(name, func, opts \\ [])



        
          
        

    

  


  

      

          @spec run(name(), func :: (-> term()), opts :: [{:on_open, term()}]) :: term()


      


Calls func through the breaker name.
If the breaker allows the call, func is invoked and its result is returned
unchanged. The result is then recorded as a success or a failure (see
Failures). If func raises, throws or exits, the
outcome is recorded the same way and the error is re-raised unchanged.
If the breaker rejects the call, func is not invoked and
{:error, :circuit_open} is returned, unless :on_open says otherwise. To
compute another result instead, wrap the call in a Rexsilient.Fallback,
which always replaces {:error, :circuit_open}.
Raises ArgumentError if no breaker is registered under name.
Options
	:on_open - the value returned when the call is rejected, instead of
{:error, :circuit_open}.

Examples
Rexsilient.CircuitBreaker.run(:payments, fn -> Payments.charge(order) end)

Rexsilient.CircuitBreaker.run(:payments, fn -> Payments.charge(order) end,
  on_open: {:error, :unavailable}
)

  



  
    
      
    
    
      start_link(opts)



        
          
        

    

  


  

      

          @spec start_link(opts :: [{:modules, [module()]}]) :: GenServer.on_start()


      


Starts the breaker manager and registers the declared breakers.
Usually started by Rexsilient, as shown in the module documentation.
Only one manager runs per node; it is registered under this module's name.
Options
	:modules - the modules that declare breakers with Rexsilient.
Required. The manager fails to start, with an ArgumentError as the
reason, if two breakers share a name or a breaker's options are
invalid.


  



  
    
      
    
    
      status(name)



        
          
        

    

  


  

      

          @spec status(name()) :: status()


      


Returns the current state of the breaker name.
Meant for inspection and debugging; see States for what
each state means. Raises ArgumentError if no breaker is registered under
name.
Examples
Rexsilient.CircuitBreaker.status(:payments)
#=> :closed

  


        

      


  

    
Rexsilient.CircuitBreaker.Recover behaviour
    



      
Decides how long a breaker waits before it lets a probe call through.
timeout/2 is called by the manager with a context whose :transition is
the change of state that starts a timer:
	{:closed, :open} - the breaker tripped. Returns how long it stays open.

	{:probing, :open} - the probe failed. Returns how long it stays open.

	{:half_open, :probing} - a probe started. Returns how long it may run
before the breaker becomes half-open again and lets another probe
through.


A successful probe closes the breaker without calling timeout/2, so the
next {:closed, :open} is the first call after a recovery.
init/1 receives the options given to recover and returns the state. The
first timeout/2 call gets that state; it returns the timeout and the new
state, which the manager passes to the next call. It is only called from the
manager, so the state can be a plain value. The state is not kept across
manager restarts: init/1 is called again.
The state can also hold what the transition alone does not tell. For
example, a {:half_open, :probing} right after another one means the
previous probe timed out.
timeout/2 runs in the manager
One manager process serves every breaker, and timeout/2 runs inside
it. A slow timeout/2 delays the timers of all breakers, and one that
raises crashes the manager: when it restarts, every breaker restarts
closed. Take care with what it does.
Built-in: Rexsilient.CircuitBreaker.Recover.BasicTimeout.
Example
defmodule MyRecover do
  @behaviour Rexsilient.CircuitBreaker.Recover

  @impl true
  def init(_opts), do: 1_000

  @impl true
  def timeout(_context, timeout), do: {timeout, timeout * 2}
end
Each timeout/2 gets the state the previous one returned: 1000, 2000,
4000, and so on. It only starts again from init/1 when the manager
restarts.

      


      
        Summary


  
    Types
  


    
      
        context()

      


        What timeout/2 knows about the change of state



    


    
      
        state()

      


        The value returned by init/1, then by each timeout/2.



    


    
      
        transition()

      


        The {from, to} change of state that starts a timer; see the module
documentation for the ones passed.



    





  
    Callbacks
  


    
      
        init(opts)

      


        Validates opts and returns the initial state.



    


    
      
        timeout(context, state)

      


        Returns how long, in milliseconds, to wait after the context's
:transition, and the new state.



    





      


      
        Types


        


  
    
      
    
    
      context()



        
          
        

    

  


  

      

          @type context() :: %{
  transition: transition(),
  outcome: Rexsilient.Classify.outcome() | nil
}


      


What timeout/2 knows about the change of state:
	:transition - the change of state that starts the timer.

	:outcome - the outcome of the call that opened the breaker, for
{:closed, :open} and {:probing, :open}. When a strategy opens the
breaker after several calls, it is the last one. nil for {:half_open, :probing}, and
when the failure was recorded with
Rexsilient.CircuitBreaker.release/4 without an outcome.


More keys may be added, so match only on the ones needed.

  



  
    
      
    
    
      state()



        
          
        

    

  


  

      

          @type state() :: term()


      


The value returned by init/1, then by each timeout/2.

  



  
    
      
    
    
      transition()



        
          
        

    

  


  

      

          @type transition() ::
  {Rexsilient.CircuitBreaker.status(), Rexsilient.CircuitBreaker.status()}


      


The {from, to} change of state that starts a timer; see the module
documentation for the ones passed.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      init(opts)



        
          
        

    

  


  

      

          @callback init(opts :: keyword()) :: state()


      


Validates opts and returns the initial state.
Called when the circuit breaker is registered, and again when the manager
restarts. Raise ArgumentError for invalid options, as
Rexsilient.Options.validate!/2 does; the error is raised again with the
circuit breaker's name.

  



  
    
      
    
    
      timeout(context, state)



        
          
        

    

  


  

      

          @callback timeout(context :: context(), state :: state()) ::
  {timeout :: non_neg_integer(), state :: state()}


      


Returns how long, in milliseconds, to wait after the context's
:transition, and the new state.

  


        

      


  

    
Rexsilient.CircuitBreaker.Recover.BasicTimeout 
    



      
Keeps the breaker open, and gives a probe, a fixed time.
Options
	:reset_timeout - how long, in milliseconds, the breaker stays open
before it lets a probe call through. Required.

	:probing_timeout - how long, in milliseconds, a probe may run before
the breaker becomes half-open again and lets another probe through.
Must be positive: with 0, every probe would time out as it starts.
Required.


Examples
recover Rexsilient.CircuitBreaker.Recover.BasicTimeout,
  reset_timeout: :timer.seconds(30),
  probing_timeout: :timer.seconds(10)

      




  

    
Rexsilient.CircuitBreaker.Strategy behaviour
    



      
Decides when a closed breaker opens.
A strategy is set with strategy when a breaker is declared:
strategy Rexsilient.CircuitBreaker.Strategy.Count, threshold: 5
init/1 receives the options and returns the state, which is passed
unchanged to record/3 and reset/1 for the life of the breaker.
Callbacks run concurrently
Unlike Rexsilient.CircuitBreaker.Recover, these callbacks run in the
processes making the calls, concurrently, so the state cannot be replaced.
Keep what changes in shared mutable storage created by init/1, :atomics or :counters,
for example.
Built-in strategies: Rexsilient.CircuitBreaker.Strategy.Count and
Rexsilient.CircuitBreaker.Strategy.SlidingWindow.
Example
defmodule MyStrategy do
  @behaviour Rexsilient.CircuitBreaker.Strategy

  @impl true
  def init(_opts), do: :counters.new(1, [])

  @impl true
  def record(counter, :failure, _duration) do
    :counters.add(counter, 1, 1)
    if :counters.get(counter, 1) >= 3, do: :trip, else: :ok
  end

  def record(_counter, :success, _duration), do: :ok

  @impl true
  def reset(counter), do: :counters.put(counter, 1, 0)
end
Every callback gets the same counter returned by init/1; only its value
changes.

      


      
        Summary


  
    Types
  


    
      
        state()

      


        The value returned by init/1.



    





  
    Callbacks
  


    
      
        init(opts)

      


        Validates opts and returns the strategy's state.



    


    
      
        record(state, result, duration)

      


        Records the result of a call.



    


    
      
        reset(state)

      


        Forgets the results recorded so far.



    





      


      
        Types


        


  
    
      
    
    
      state()



        
          
        

    

  


  

      

          @type state() :: term()


      


The value returned by init/1.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      init(opts)



        
          
        

    

  


  

      

          @callback init(opts :: keyword()) :: state()


      


Validates opts and returns the strategy's state.
Called when the circuit breaker is registered. Raise ArgumentError for
invalid options, as Rexsilient.Options.validate!/2 does; the error is
raised again with the circuit breaker's name.

  



  
    
      
    
    
      record(state, result, duration)



        
          
        

    

  


  

      

          @callback record(
  state :: state(),
  result :: Rexsilient.Classify.result(),
  duration :: non_neg_integer() | nil
) :: :ok | :trip


      


Records the result of a call.
Called for every call made while the breaker is closed, successes
included; probes are not recorded. Return :trip to open the breaker,
:ok otherwise.
duration is how long the call took, in :native time units, or nil
when it was released with Rexsilient.CircuitBreaker.release/4 directly.
To compare it with an option given in milliseconds, convert the option
once in init/1 with System.convert_time_unit(value, :millisecond, :native)
instead of converting every duration.

  



  
    
      
    
    
      reset(state)



        
          
        

    

  


  

      

          @callback reset(state :: state()) :: :ok


      


Forgets the results recorded so far.
Called just before the breaker closes.

  


        

      


  

    
Rexsilient.CircuitBreaker.Strategy.Count 
    



      
Opens the breaker after a number of failures.
Failures are counted from the moment the breaker was last closed; successes
do not reset the count.
Options
	:threshold - the number of failures that opens the breaker. Required.

Examples
strategy Rexsilient.CircuitBreaker.Strategy.Count, threshold: 5

      




  

    
Rexsilient.CircuitBreaker.Strategy.SlidingWindow 
    



      
Opens the breaker after a number of failures within a time window.
Only failures are tracked: the breaker opens when threshold failures
happen within window milliseconds of each other. Successes do not affect
it, and failures older than the window stop counting.
Options
	:threshold - the number of failures that opens the breaker. Required.
With 1, the first failure opens the breaker and :window has no
effect, like Rexsilient.CircuitBreaker.Strategy.Count with the same
threshold.
The breaker keeps the time of the last threshold - 1 failures, 8 bytes
each, so memory grows with the threshold.

	:window - the time, in milliseconds, those failures must fit in.
Required.


Examples
strategy Rexsilient.CircuitBreaker.Strategy.SlidingWindow,
  threshold: 5,
  window: :timer.seconds(10)

      




  

    
Rexsilient.Classify behaviour
    



      
Decides whether the outcome of a call counts as a failure.
Every module that uses Rexsilient implements this behaviour, and the
circuit breakers, retries and fallbacks it declares use it. The defaults
count :error and {:error, _} returns, and every raise, throw or exit, as
failures; any other return counts as a success.
Override classify/1 to change how returned values are classified:
defmodule MyApp.Resilience do
  use Rexsilient

  circuit_breaker :payments do
    # ...
  end

  @impl true
  def classify({:error, %{status: status}}) when status >= 500, do: :failure
  def classify(_), do: :success
end
Override classify/2 to change how raises, throws and exits are classified.
The two are independent: overriding classify/1 keeps the default
classify/2, so a catch-all clause on returns never turns an exception into
a success.
@impl true
def classify(:error, %Mint.TransportError{}), do: :failure
def classify(_kind, _reason), do: :success
Circuit breakers and retries re-raise the exception unchanged either way;
only how it is counted changes. A fallback replaces it when it counts as a
failure, and re-raises it otherwise.
To classify one declaration differently from the others in the same module,
name other functions with Rexsilient.classify_with/1.

      


      
        Summary


  
    Types
  


    
      
        outcome()

      


        What a call produced: {:value, value} for a value it returned, or
{kind, reason} for a raise, throw or exit, as given to catch.



    


    
      
        result()

      


        Whether a call succeeded or failed.



    





  
    Callbacks
  


    
      
        classify(value)

      


        Classifies a value returned by the call.



    


    
      
        classify(kind, reason)

      


        Classifies a call that raised, threw or exited.



    





      


      
        Types


        


  
    
      
    
    
      outcome()



        
          
        

    

  


  

      

          @type outcome() ::
  {:value, value :: term()}
  | {kind :: :error | :throw | :exit, reason :: term()}


      


What a call produced: {:value, value} for a value it returned, or
{kind, reason} for a raise, throw or exit, as given to catch.

  



  
    
      
    
    
      result()



        
          
        

    

  


  

      

          @type result() :: :success | :failure


      


Whether a call succeeded or failed.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      classify(value)



        
          
        

    

  


  

      

          @callback classify(value :: term()) :: result()


      


Classifies a value returned by the call.

  



  
    
      
    
    
      classify(kind, reason)



        
          
        

    

  


  

      

          @callback classify(kind :: :error | :throw | :exit, reason :: term()) :: result()


      


Classifies a call that raised, threw or exited.
kind and reason are the ones given to catch: for a raise, kind is
:error and reason the exception.

  


        

      


  

    
Rexsilient.Decorator 
    



      
Runs a function through a circuit breaker, a retry, a fallback or a policy
by annotating it.
Instead of wrapping every call in Rexsilient.CircuitBreaker.run/3, a
function can be marked with @circuit_breaker so that all its calls go
through the circuit breaker:
defmodule MyApp.Payments do
  use Rexsilient.Decorator

  @circuit_breaker :payments
  def charge(order) do
    PaymentsClient.charge(order)
  end
end
MyApp.Payments.charge(order) now behaves like:
Rexsilient.CircuitBreaker.run(:payments, fn -> PaymentsClient.charge(order) end)
The circuit breaker must be declared with Rexsilient and registered as
usual; see Rexsilient.CircuitBreaker for its results and how failures are
counted.
@retry and @fallback work the same way, with Rexsilient.Retry.run/2
and Rexsilient.Fallback.run/3. The fallback function is called with the
decorated function's arguments.
Options
To pass options to Rexsilient.CircuitBreaker.run/3, give a keyword list
with the circuit breaker's name under :name:
@circuit_breaker name: :prices, on_open: {:error, :unavailable}
def fetch_price(sku) do
  PricesClient.fetch(sku)
end
@retry, @fallback and @policy take only a name.
Stacking
@fallback, @retry and @circuit_breaker can be used on the same
function. They always nest in the same order, whatever the order they are
written in:
@fallback :prices
@retry :prices
@circuit_breaker :prices
def fetch_price(sku) do
  PricesClient.fetch(sku)
end
behaves like:
Rexsilient.Fallback.run(:prices, fn sku ->
  Rexsilient.Retry.run(:prices, fn ->
    Rexsilient.CircuitBreaker.run(:prices, fn -> PricesClient.fetch(sku) end)
  end)
end, sku)
Every attempt goes through the breaker and is counted. The retry stops as
soon as the breaker is open, and the fallback replaces whatever outcome is
left: the last attempt's failure or the breaker's rejection.
When the same stack is used on several functions, declare it once as a
policy with Rexsilient.policy/2 and use @policy:
# in the module that uses Rexsilient
policy :prices do
  fallback :prices
  retry :prices
  circuit_breaker :prices
end

# in the decorated module
@policy :prices
def fetch_price(sku) do
  PricesClient.fetch(sku)
end
A policy nests in the same order. @policy cannot be combined with the
other decorators on the same function.
For another order, or the same pattern twice, decorate one function per
layer, each calling the next:
# The breaker counts a whole retry sequence as one call.
@circuit_breaker :prices
def fetch_price(sku), do: fetch_price_with_retry(sku)

@doc false
@retry :prices
def fetch_price_with_retry(sku), do: PricesClient.fetch(sku)
The inner function must be public, so calling it directly skips the outer
layer.
Rules
	The attribute goes right before the function's first clause and applies
to every clause of that name and arity.

	Only public functions (def) can be decorated. Using it on defp or a
macro fails compilation, and so does an attribute that is not followed
by a function.

	Recursive calls from inside the function go through the decorators too.



      




  

    
Rexsilient.Fallback 
    



      
Replaces the outcome of a failed call with the result of another function.
A fallback is declared in a module that uses Rexsilient, with the function
to call instead:
defmodule MyApp.Resilience do
  use Rexsilient

  fallback :prices do
    function :cached_price
  end

  def cached_price(sku), do: Cache.last_price(sku)
end
and used with @fallback :prices from Rexsilient.Decorator, which calls
the fallback function with the decorated function's arguments:
defmodule MyApp.Prices do
  use Rexsilient.Decorator

  @fallback :prices
  def fetch(sku) do
    PricesClient.fetch(sku)
  end
end
or, without a decorator, with run/3:
Rexsilient.Fallback.run(:prices, fn sku -> PricesClient.fetch(sku) end, sku)
Settings
	function - the function called on failure: a name, for a function in
the declaring module, or {module, name} for one in another module.
Required.

	classify_with - the name of the functions, in the declaring module,
that decide which outcomes are failures and so are replaced. Defaults
to classify; see Rexsilient.Classify.


Behaviour
The call is made. If its outcome is a success, it is returned unchanged.
If it is a failure, the fallback function is called with the same
arguments, and its result is returned instead; a raise, throw or exit
counted as a failure is not re-raised.
{:error, :circuit_open} is always replaced, without asking the classifier:
a circuit breaker rejected the call, so there is no result to keep. This
lets a fallback declared around a breaker answer while the breaker is open.
An error raised by the fallback function itself propagates to the caller.

      


      
        Summary


  
    Types
  


    
      
        name()

      


        The name a fallback is declared with.



    





  
    Functions
  


    
      
        run(name, func, args \\ [])

      


        Calls func with args through the fallback name.



    





      


      
        Types


        


  
    
      
    
    
      name()



        
          
        

    

  


  

      

          @type name() :: atom()


      


The name a fallback is declared with.

  


        

      

      
        Functions


        


    

  
    
      
    
    
      run(name, func, args \\ [])



        
          
        

    

  


  

      

          @spec run(name(), func :: (term() -> term()), args :: term()) :: term()


      


Calls func with args through the fallback name.
args is passed to func as its only argument, and to the fallback
function in the same way, so both take one argument. Use a list or a tuple
to pass several values. Returns func's result, or the fallback's on
failure; see Behaviour.
Raises ArgumentError if no fallback is registered under name.
Examples
Rexsilient.Fallback.run(:prices, fn sku -> Prices.fetch(sku) end, sku)

  


        

      


  

    
Rexsilient.Jitter 
    



      
Randomized delays for retrying failed calls.
When many callers fail at the same moment and all retry after the same
delay, they hit the dependency again at the same moment too. Adding
randomness to the delay, called jitter, spreads the retries out so the
dependency is not flooded when it comes back.
Each function implements one strategy. full/3 and equal/3 grow the
delay exponentially with each attempt, starting from base_delay;
decorrelated/3 bases each delay on the previous one. None goes above
max_delay. Delays are in whatever unit base_delay and max_delay use,
usually milliseconds.

      


      
        Summary


  
    Functions
  


    
      
        decorrelated(base_delay, max_delay, previous_delay)

      


        Returns a random delay between base_delay and three times
previous_delay, capped at max_delay.



    


    
      
        equal(base_delay, max_delay, attempt)

      


        Returns half of the exponential backoff for attempt, plus a random amount
up to the other half.



    


    
      
        full(base_delay, max_delay, attempt)

      


        Returns a random delay between 0 and the exponential backoff for
attempt.



    





      


      
        Functions


        


  
    
      
    
    
      decorrelated(base_delay, max_delay, previous_delay)



        
          
        

    

  


  

      

          @spec decorrelated(
  base_delay :: non_neg_integer(),
  max_delay :: non_neg_integer(),
  previous_delay :: non_neg_integer()
) :: non_neg_integer()


      


Returns a random delay between base_delay and three times
previous_delay, capped at max_delay.
Unlike full/3 and equal/3, it does not use the attempt number: each
delay is based on the previous one. Pass base_delay as previous_delay on
the first retry.
Examples
delay = Rexsilient.Jitter.decorrelated(100, 10_000, 100)
# a random integer from 100 to 300

Rexsilient.Jitter.decorrelated(100, 10_000, delay)

  



  
    
      
    
    
      equal(base_delay, max_delay, attempt)



        
          
        

    

  


  

      

          @spec equal(
  base_delay :: non_neg_integer(),
  max_delay :: non_neg_integer(),
  attempt :: non_neg_integer()
) :: non_neg_integer()


      


Returns half of the exponential backoff for attempt, plus a random amount
up to the other half.
The backoff is computed as in full/3. Every delay is at least half of it,
so retries are spread out while never following each other too closely.
Examples
Rexsilient.Jitter.equal(100, 10_000, 3)
# a random value from 400 to 800

  



  
    
      
    
    
      full(base_delay, max_delay, attempt)



        
          
        

    

  


  

      

          @spec full(
  base_delay :: non_neg_integer(),
  max_delay :: non_neg_integer(),
  attempt :: non_neg_integer()
) :: non_neg_integer()


      


Returns a random delay between 0 and the exponential backoff for
attempt.
The backoff is base_delay * 2 ** attempt, capped at max_delay, and
attempt starts at 0. This spreads retries the most, but a delay may be
very short.
Examples
Rexsilient.Jitter.full(100, 10_000, 3)
# a random integer from 0 to 800

  


        

      


  

    
Rexsilient.Notifier behaviour
    



      
Tells notifiers what the patterns are doing.
A notifier is a module that implements this behaviour, listed in the
:notifiers option of Rexsilient:
defmodule MyApp.Notifier do
  @behaviour Rexsilient.Notifier

  require Logger

  @impl true
  def notify(:after, :retry, %{result: :failure} = state) do
    Logger.warning("retry #{inspect(state.name)}: attempt #{state.attempt} failed")
  end

  def notify(_moment, _kind, _state), do: :ok
end

children = [
  {Rexsilient, modules: [MyApp.Resilience], notifiers: [MyApp.Notifier]}
]
Every notifier gets every notification; match on kind and the :name in
state to keep only the ones needed. Without notifiers, nothing is sent.
Moments
kind is the pattern, and state a map that always has its :name.
Every :before also has :monotonic_time and :system_time, and every
:after has :monotonic_time and the :duration since its :before, all
in native time units, measured in the calling process.
:circuit_breaker, around calls made with Rexsilient.CircuitBreaker.run/3:
	:before - an allowed call is about to run.

	:after - it finished, with its :result and :outcome.

	:rejected - the breaker rejected the call, with its :system_time.


Calls made with Rexsilient.CircuitBreaker.acquire/1 and
Rexsilient.CircuitBreaker.release/4 directly send none of these.
:circuit_breaker, when the breaker changes state, with the state it was
in as :from, and the :system_time at which the change happened:
	:open - it opened, with the :timeout before it becomes half-open,
and the :outcome that opened it. When forced with
Rexsilient.CircuitBreaker.force_open/1, :timeout is :infinity
and :outcome is nil.

	:half_open - it lets the next call through as a probe.

	:probing - a probe started, with the :timeout before another one
is let through.

	:closed - a probe succeeded, it was forced closed, or the breaker
manager restarted while it was not closed.


A change made with Rexsilient.CircuitBreaker.force_open/1 or
Rexsilient.CircuitBreaker.force_close/1 also has forced: true, and
one made by a manager restart has restart: true.
:retry:
	:before - an attempt is about to run, with its :attempt number.

	:after - it finished, with its :attempt, :result and :outcome.

	:delay - it failed and the next attempt waits :delay milliseconds,
with its :attempt and :outcome.

	:stop - it failed and no attempt follows, with its :attempt,
:outcome, the :duration of the whole run, and the :reason:
:attempts when none remain, :strategy when the strategy stopped,
:circuit_open when the attempt returned {:error, :circuit_open}.


:fallback, only when the fallback function is called:
	:before - it is about to run, with the :outcome it replaces.

	:after - it returned, with its :outcome.


:result is :success or :failure, as classified, and :outcome is a
Rexsilient.Classify.outcome/0. More moments and keys may be added, so
end with a catch-all clause.
State changes are notified from both the calling processes and the breaker
manager, so they may arrive out of order; use :system_time to order them.
Process
Notifications are sent to a single notifier process, started by
Rexsilient. The call being notified does not wait for it, so :before
is handled after the call has started.
For each notification, every notifier is called in its own task, and the
next notification waits for all of them, so each notifier sees them in the
order the notifier process received them. A notifier that raises or exits
only crashes its own task, which logs the error; one that takes longer than
5 seconds is killed, and the timeout is logged. Either way it is skipped for that notification, and
the others are not affected.
The notifier mailbox has no limit
Notifications wait in the notifier process's mailbox, which has no limit.
When they arrive faster than the notifiers handle them, for example with a
notifier that takes a few milliseconds under high traffic, they arrive
later and later, and the mailbox, and so memory, keeps growing.
Rexsilient.Notifier.TelemetryNotifier, the default, is the exception: it
is called in the calling process, like any :telemetry event, so its
handlers see the caller's context. Notifications sent by the breaker
manager still go through the notifier process, so the manager never runs
handlers.

      


      
        Summary


  
    Types
  


    
      
        kind()

      


        The pattern that sends it.



    


    
      
        moment()

      


        When the notification is sent; see Moments.



    





  
    Callbacks
  


    
      
        notify(moment, kind, state)

      


        Called, in a task, for every notification; see Process.



    





  
    Functions
  


    
      
        child_spec(init_arg)

      


        Returns a specification to start this module under a supervisor.



    





      


      
        Types


        


  
    
      
    
    
      kind()



        
          
        

    

  


  

      

          @type kind() :: :circuit_breaker | :fallback | :retry


      


The pattern that sends it.

  



  
    
      
    
    
      moment()



        
          
        

    

  


  

      

          @type moment() ::
  :before
  | :after
  | :rejected
  | :open
  | :half_open
  | :probing
  | :closed
  | :delay
  | :stop


      


When the notification is sent; see Moments.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      notify(moment, kind, state)



        
          
        

    

  


  

      

          @callback notify(moment(), kind(), state :: map()) :: term()


      


Called, in a task, for every notification; see Process.
The return value is ignored.

  


        

      

      
        Functions


        


  
    
      
    
    
      child_spec(init_arg)



        
          
        

    

  


  

Returns a specification to start this module under a supervisor.
See Supervisor.

  


        

      


  

    
Rexsilient.Notifier.TelemetryNotifier 
    



      
The default notifier: emits every notification as a :telemetry event.
The event name is [:rexsilient, kind, moment], following the
:telemetry.span/3 conventions: :before is emitted as :start and
:after as :stop. The retry :stop moment is emitted as :give_up, so
it does not clash with the :stop event of each attempt.
The numeric keys of the notification's state, :monotonic_time,
:system_time, :duration, :delay and :timeout, are the measurements;
every other key is metadata. A :timeout of :infinity stays in the
metadata. See Rexsilient.Notifier for what each moment means.
Events
[:rexsilient, :circuit_breaker, event]:
	Event	Measurements	Metadata
	:start	monotonic_time, system_time	name
	:stop	monotonic_time, duration	name, result, outcome
	:rejected	system_time	name
	:open	system_time, timeout	name, from, outcome, forced¹
	:half_open	system_time	name, from
	:probing	system_time, timeout	name, from, outcome
	:closed	system_time	name, from, forced¹, restart¹

¹ Only present when the change was forced with
Rexsilient.CircuitBreaker.force_open/1 or
Rexsilient.CircuitBreaker.force_close/1, or caused by a manager restart.
A forced :open has timeout: :infinity, in the metadata.
[:rexsilient, :retry, event]:
	Event	Measurements	Metadata
	:start	monotonic_time, system_time	name, attempt
	:stop	monotonic_time, duration	name, attempt, result, outcome
	:delay	delay	name, attempt, outcome
	:give_up	duration	name, attempt, outcome, reason

[:rexsilient, :fallback, event]:
	Event	Measurements	Metadata
	:start	monotonic_time, system_time	name, outcome (the one replaced)
	:stop	monotonic_time, duration	name, outcome

Times and duration are in native time units, delay and timeout in
milliseconds. result is :success or :failure, and outcome is a
Rexsilient.Classify.outcome/0.
Example
:telemetry.attach(
  "log-open-breakers",
  [:rexsilient, :circuit_breaker, :open],
  fn _event, _measurements, %{name: name, from: from}, _config ->
    Logger.warning("breaker #{inspect(name)} opened from #{from}")
  end,
  nil
)
Handlers run in the calling process
Unlike other notifiers, it runs in the calling process, so handlers must be
fast; see Process.

      




  

    
Rexsilient.Options 
    



      
Validates the options given to strategies and recover modules.
The built-in modules use it in their init/1, and custom ones can too, so
that invalid options fail the same way: with an ArgumentError that
Rexsilient raises again with the declaration's name.
@impl true
def init(opts) do
  Rexsilient.Options.validate!(opts, delay: :non_neg_integer, budget: :pos_integer)
end

      


      
        Summary


  
    Types
  


    
      
        type()

      


        The type an option must have



    





  
    Functions
  


    
      
        validate!(opts, spec)

      


        Validates opts against spec, a keyword list of key: type.



    





      


      
        Types


        


  
    
      
    
    
      type()



        
          
        

    

  


  

      

          @type type() :: :pos_integer | :non_neg_integer


      


The type an option must have:
	:pos_integer - an integer greater than 0.

	:non_neg_integer - an integer greater than or equal to 0.



  


        

      

      
        Functions


        


  
    
      
    
    
      validate!(opts, spec)



        
          
        

    

  


  

      

          @spec validate!(opts :: term(), spec :: [{atom(), type()}]) :: %{
  required(atom()) => term()
}


      


Validates opts against spec, a keyword list of key: type.
Every key in spec is required, and keys not in spec are rejected.
Returns the options as a map. Raises ArgumentError otherwise.
Examples
Rexsilient.Options.validate!([threshold: 5], threshold: :pos_integer)
#=> %{threshold: 5}

Rexsilient.Options.validate!([threshold: 0], threshold: :pos_integer)
** (ArgumentError) threshold must be a positive integer, got: 0

  


        

      


  

    
Rexsilient.Retry 
    



      
Calls a function again when it fails.
A retry is declared in a module that uses Rexsilient:
defmodule MyApp.Resilience do
  use Rexsilient

  alias Rexsilient.Retry.Strategy

  retry :payments do
    attempts 4
    strategy Strategy.Exponential, base_delay: 100, max_delay: 5_000, jitter: :full
  end
end
and used with @retry :payments from Rexsilient.Decorator:
defmodule MyApp.Payments do
  use Rexsilient.Decorator

  @retry :payments
  def charge(order) do
    PaymentsClient.charge(order)
  end
end
or, without a decorator, with run/2:
Rexsilient.Retry.run(:payments, fn -> PaymentsClient.charge(order) end)
Settings
	attempts - the total number of calls, the first one included. A
positive integer, or :infinity to leave the limit to the strategy.
Required.

	strategy - the module that decides how long to wait before the next
attempt, or to stop, and its options. Required. See
Rexsilient.Retry.Strategy.

	classify_with - the name of the functions, in the declaring module,
that decide which outcomes are failures and so are retried. Defaults to
classify; see Rexsilient.Classify.


Behaviour
The function is called. If its outcome is a success, it is returned. If it
is a failure and attempts remain, the strategy is asked for a delay, the
caller sleeps for it, and the function is called again.
When no attempts remain, or the strategy stops, the last outcome is
returned unchanged: the value the function returned, or what it raised,
threw or exited with, re-raised with its original stacktrace.
{:error, :circuit_open} is never retried: a circuit breaker just said the
dependency is down, and retrying would only wait for the same answer. It is
a failure whatever classify says, and it ends the run at once.
The delay runs in the calling process, with Process.sleep/1.
What is retried by default
The default classify counts every {:error, _} and every raise, throw
and exit as a failure, so all of them are retried. That includes bugs,
such as a FunctionClauseError, which then crash only after every
attempt and its delay. It also includes calls that are not idempotent
and may have taken effect before failing. Use classify_with to retry
only the failures that are safe and worth retrying.

      


      
        Summary


  
    Types
  


    
      
        name()

      


        The name a retry is declared with.



    





  
    Functions
  


    
      
        run(name, func)

      


        Calls func through the retry name.



    





      


      
        Types


        


  
    
      
    
    
      name()



        
          
        

    

  


  

      

          @type name() :: atom()


      


The name a retry is declared with.

  


        

      

      
        Functions


        


  
    
      
    
    
      run(name, func)



        
          
        

    

  


  

      

          @spec run(name(), func :: (-> term())) :: term()


      


Calls func through the retry name.
Returns the outcome of the last attempt; see Behaviour.
Raises ArgumentError if no retry is registered under name.
Examples
Rexsilient.Retry.run(:payments, fn -> Payments.charge(order) end)

  


        

      


  

    
Rexsilient.Retry.Strategy behaviour
    



      
Decides how long a retry waits before the next attempt, or whether it
stops.
A strategy is set with strategy when a retry is declared:
strategy Rexsilient.Retry.Strategy.Constant, delay: 500
init/1 receives the options and returns the state. Each run starts from
that state: the first delay/2 call gets it, and returns the delay and the
new state, which is passed to the next call of the same run. A run happens
entirely in one process, so the state can be a plain value.
delay/2 is only called after a failed attempt that is not the last one:
attempts is enforced by the core, so a strategy does not need to count
them. Return :stop to give up earlier, for example after a time budget or
on a specific error.
Built-in strategies: Rexsilient.Retry.Strategy.Constant,
Rexsilient.Retry.Strategy.Exponential and
Rexsilient.Retry.Strategy.Decorrelated.
Example
defmodule MyStrategy do
  @behaviour Rexsilient.Retry.Strategy

  @impl true
  def init(_opts), do: 100

  @impl true
  def delay(_context, delay), do: {:retry, delay, delay * 2}
end
Within a run, it waits 100, 200, 400, and so on. Every run starts again from
the 100 returned by init/1.

      


      
        Summary


  
    Types
  


    
      
        context()

      


        What delay/2 knows about the attempt that just failed



    


    
      
        state()

      


        The value returned by init/1, then by each delay/2.



    





  
    Callbacks
  


    
      
        delay(context, state)

      


        Returns {:retry, delay, state} to wait delay milliseconds and try
again, or :stop to give up and return the last outcome.



    


    
      
        init(opts)

      


        Validates opts and returns the initial state.



    





      


      
        Types


        


  
    
      
    
    
      context()



        
          
        

    

  


  

      

          @type context() :: %{attempt: pos_integer(), outcome: Rexsilient.Classify.outcome()}


      


What delay/2 knows about the attempt that just failed:
	:attempt - its number, starting at 1.

	:outcome - what it returned, raised, threw or exited with.


More keys may be added, so match only on the ones needed.

  



  
    
      
    
    
      state()



        
          
        

    

  


  

      

          @type state() :: term()


      


The value returned by init/1, then by each delay/2.

  


        

      

      
        Callbacks


        


  
    
      
    
    
      delay(context, state)



        
          
        

    

  


  

      

          @callback delay(context :: context(), state :: state()) ::
  {:retry, delay :: non_neg_integer(), state :: state()} | :stop


      


Returns {:retry, delay, state} to wait delay milliseconds and try
again, or :stop to give up and return the last outcome.

  



  
    
      
    
    
      init(opts)



        
          
        

    

  


  

      

          @callback init(opts :: keyword()) :: state()


      


Validates opts and returns the initial state.
Called when the retry is registered. Raise ArgumentError for invalid
options, as Rexsilient.Options.validate!/2 does; the error is raised
again with the retry's name.

  


        

      


  

    
Rexsilient.Retry.Strategy.Constant 
    



      
Waits the same time before every attempt.
Options
	:delay - how long, in milliseconds, to wait before each attempt.
Required.

Examples
strategy Rexsilient.Retry.Strategy.Constant, delay: 500

      




  

    
Rexsilient.Retry.Strategy.Decorrelated 
    



      
Waits a random time based on the previous wait, up to a maximum.
Each wait is a random value from base_delay to three times the previous
wait, capped at max_delay; see Rexsilient.Jitter.decorrelated/3. Waits
grow on average, like Rexsilient.Retry.Strategy.Exponential, but each
caller's waits drift apart.
Options
	:base_delay - the shortest wait, in milliseconds, and the base of the
first one. Required.

	:max_delay - the longest wait, in milliseconds. Required.


Examples
strategy Rexsilient.Retry.Strategy.Decorrelated,
  base_delay: 100,
  max_delay: 5_000

      




  

    
Rexsilient.Retry.Strategy.Exponential 
    



      
Doubles the wait after every attempt, up to a maximum.
The wait after attempt n is base_delay * 2 ** (n - 1), capped at
max_delay: with a base_delay of 100, it waits 100, 200, 400, ...
Options
	:base_delay - the wait, in milliseconds, after the first attempt.
Required.

	:max_delay - the longest wait, in milliseconds. Required.

	:jitter - how the wait is randomized, so that callers failing at the
same time do not retry at the same time. :none (the default) uses
the exact wait, :full a random one from 0 to it (see
Rexsilient.Jitter.full/3), and :equal a random one from half of it
to it (see Rexsilient.Jitter.equal/3).


Examples
strategy Rexsilient.Retry.Strategy.Exponential,
  base_delay: 100,
  max_delay: 5_000,
  jitter: :full

